データセット詳細

MoG+ RDF

MoG+ RDF は、理化学研究所バイオリソース研究センター（RIKEN BioResource Research Center）が提供するマウスゲノム変異データベース MoG+（Mouse Genome database with high added value）をRDF化したデータセットです。MoG+ は、野生由来系統や古典的近交系を含むマウス系統のゲノム変異情報を提供し、マウス系統間のゲノム多型の比較解析に利用できます。本RDFデータセットの利用にあたっては、MoG+ の Data Release Policy を参照してください： https://molossinus.brc.riken.jp/mogplus3/about/policy オリジナルのMoG+データファイルは以下から取得できます： https://molossinus.brc.riken.jp/pub/

データセット仕様

タグ	Genome Mouse Variation
提供元	Original
登録区分	Submitted
データ提供者	理研バイオリソース研究センター
作成者	高田豊行理研バイオリソース研究センター桝屋啓志理研バイオリソース研究センター
公開日	2026-07-03
ライセンス	https://molossinus.brc.riken.jp/mogplus3/about/policy MoG+ is licensed under a Creative Commons Attribution (CC-BY) 4.0 License.
ダウンロード	/website/ja/download/#mogplus
SPARQLエンドポイント	https://rdfportal.org/primary/sparql

データセット統計

Triples: 12376862684

Subjects: 1405915030

Properties: 70

Objects: 1474488946

Classes: 15

SPARQLクエリ例

例 1

エンドポイントで実行

# Retrieve basic information about a variant

PREFIX rdf:     <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs:    <http://www.w3.org/2000/01/rdf-schema#>
PREFIX faldo:   <http://biohackathon.org/resource/faldo#>
PREFIX gvo:     <http://genome-variation.org/resource#>
PREFIX vcf:     <http://genome-variation.org/resource/vcf#>
PREFIX vep:     <http://genome-variation.org/resource/vep#>
PREFIX snpeff:  <http://genome-variation.org/resource/snpeff#>
PREFIX mogplus: <http://identifiers.org/mogplus/ontology#>
PREFIX med2rdf: <http://med2rdf.org/ontology/med2rdf#>
PREFIX brso:    <http://purl.jp/bio/10/brso/>
PREFIX obo:     <http://purl.obolibrary.org/obo/>
PREFIX ensg:    <http://rdf.ebi.ac.uk/resource/ensembl/>
PREFIX mogbs:   <http://identifiers.org/mogplus/bioresource/>
PREFIX mgi:     <http://identifiers.org/mgi/>

SELECT ?variant ?pos ?ref ?alt
FROM <http://rdfportal.org/dataset/mogplus>
WHERE {
  ?variant a ?type ;
           gvo:pos ?pos ;
           gvo:ref ?ref ;
           gvo:alt ?alt .

  FILTER(?type IN (gvo:SNV, gvo:Variation))
}
ORDER BY ?pos
LIMIT 100

例 2

エンドポイントで実行

# Retrieve variants present in a specific strain (FLS_Shi)

PREFIX rdf:     <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs:    <http://www.w3.org/2000/01/rdf-schema#>
PREFIX faldo:   <http://biohackathon.org/resource/faldo#>
PREFIX gvo:     <http://genome-variation.org/resource#>
PREFIX vcf:     <http://genome-variation.org/resource/vcf#>
PREFIX vep:     <http://genome-variation.org/resource/vep#>
PREFIX snpeff:  <http://genome-variation.org/resource/snpeff#>
PREFIX mogplus: <http://identifiers.org/mogplus/ontology#>
PREFIX med2rdf: <http://med2rdf.org/ontology/med2rdf#>
PREFIX brso:    <http://purl.jp/bio/10/brso/>
PREFIX obo:     <http://purl.obolibrary.org/obo/>
PREFIX ensg:    <http://rdf.ebi.ac.uk/resource/ensembl/>
PREFIX mogbs:   <http://identifiers.org/mogplus/bioresource/>
PREFIX mgi:     <http://identifiers.org/mgi/>

SELECT ?variant ?pos ?ref ?alt ?genotype ?ad_ref ?ad_alt
FROM <http://rdfportal.org/dataset/mogplus>
WHERE {
  ?variant vcf:has_genotype_call ?call ;
           gvo:pos ?pos ;
           gvo:ref ?ref ;
           gvo:alt ?alt .

  ?call med2rdf:sample mogbs:FLS_Shi ;
        vcf:genotype ?genotype .

  OPTIONAL { ?call vcf:ad_ref ?ad_ref }
  OPTIONAL { ?call vcf:ad_alt ?ad_alt }
}
ORDER BY ?pos
LIMIT 100

例 3

エンドポイントで実行

# Retrieve strains carrying a specific variant (GRCm39#3050118-G-A)

PREFIX rdf:     <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs:    <http://www.w3.org/2000/01/rdf-schema#>
PREFIX faldo:   <http://biohackathon.org/resource/faldo#>
PREFIX gvo:     <http://genome-variation.org/resource#>
PREFIX vcf:     <http://genome-variation.org/resource/vcf#>
PREFIX vep:     <http://genome-variation.org/resource/vep#>
PREFIX snpeff:  <http://genome-variation.org/resource/snpeff#>
PREFIX mogplus: <http://identifiers.org/mogplus/ontology#>
PREFIX med2rdf: <http://med2rdf.org/ontology/med2rdf#>
PREFIX brso:    <http://purl.jp/bio/10/brso/>
PREFIX obo:     <http://purl.obolibrary.org/obo/>
PREFIX ensg:    <http://rdf.ebi.ac.uk/resource/ensembl/>
PREFIX mogbs:   <http://identifiers.org/mogplus/bioresource/>
PREFIX mgi:     <http://identifiers.org/mgi/>

SELECT ?strain ?strain_label ?genotype ?ad_ref ?ad_alt ?dp
FROM <http://rdfportal.org/dataset/mogplus>
WHERE {
  <http://identifiers.org/mogplus/v3/1/GRCm39#3050118-G-A>
      vcf:has_genotype_call ?call .

  ?call med2rdf:sample ?strain ;
        vcf:genotype ?genotype .

  OPTIONAL { ?call vcf:ad_ref ?ad_ref }
  OPTIONAL { ?call vcf:ad_alt ?ad_alt }
  OPTIONAL { ?call vcf:sample_read_depth ?dp }
  OPTIONAL { ?strain rdfs:label ?strain_label }
}
ORDER BY ?strain_label
LIMIT 100

例 4

エンドポイントで実行

# Retrieve variants within a specific coordinate range

PREFIX rdf:     <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs:    <http://www.w3.org/2000/01/rdf-schema#>
PREFIX faldo:   <http://biohackathon.org/resource/faldo#>
PREFIX gvo:     <http://genome-variation.org/resource#>
PREFIX vcf:     <http://genome-variation.org/resource/vcf#>
PREFIX vep:     <http://genome-variation.org/resource/vep#>
PREFIX snpeff:  <http://genome-variation.org/resource/snpeff#>
PREFIX mogplus: <http://identifiers.org/mogplus/ontology#>
PREFIX med2rdf: <http://med2rdf.org/ontology/med2rdf#>
PREFIX brso:    <http://purl.jp/bio/10/brso/>
PREFIX obo:     <http://purl.obolibrary.org/obo/>
PREFIX ensg:    <http://rdf.ebi.ac.uk/resource/ensembl/>
PREFIX mogbs:   <http://identifiers.org/mogplus/bioresource/>
PREFIX mgi:     <http://identifiers.org/mgi/>

SELECT ?variant ?pos ?ref ?alt
FROM <http://rdfportal.org/dataset/mogplus>
WHERE {
  ?variant gvo:pos ?pos ;
           gvo:ref ?ref ;
           gvo:alt ?alt ;
           faldo:location ?loc .

  ?loc faldo:reference <http://identifiers.org/mco/1/GRCm39> .

  FILTER(?pos >= 3050000 && ?pos <= 3100000)
}
ORDER BY ?pos

例 5

エンドポイントで実行

# Retrieve variants located within a specific Ensembl gene (ENSMUSG00000051951)

PREFIX rdf:     <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs:    <http://www.w3.org/2000/01/rdf-schema#>
PREFIX faldo:   <http://biohackathon.org/resource/faldo#>
PREFIX gvo:     <http://genome-variation.org/resource#>
PREFIX vcf:     <http://genome-variation.org/resource/vcf#>
PREFIX vep:     <http://genome-variation.org/resource/vep#>
PREFIX snpeff:  <http://genome-variation.org/resource/snpeff#>
PREFIX mogplus: <http://identifiers.org/mogplus/ontology#>
PREFIX med2rdf: <http://med2rdf.org/ontology/med2rdf#>
PREFIX brso:    <http://purl.jp/bio/10/brso/>
PREFIX obo:     <http://purl.obolibrary.org/obo/>
PREFIX ensg:    <http://rdf.ebi.ac.uk/resource/ensembl/>
PREFIX mogbs:   <http://identifiers.org/mogplus/bioresource/>
PREFIX mgi:     <http://identifiers.org/mgi/>

SELECT ?variant ?pos ?ref ?alt
FROM <http://rdfportal.org/dataset/mogplus>
WHERE {
  ?variant mogplus:overlaps_gene ensg:ENSMUSG00000051951 ;
           gvo:pos ?pos ;
           gvo:ref ?ref ;
           gvo:alt ?alt .
}
ORDER BY ?pos

例 6

エンドポイントで実行

# Search using a VEP consequence (ex. SO_0001628)

PREFIX rdf:     <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs:    <http://www.w3.org/2000/01/rdf-schema#>
PREFIX faldo:   <http://biohackathon.org/resource/faldo#>
PREFIX gvo:     <http://genome-variation.org/resource#>
PREFIX vcf:     <http://genome-variation.org/resource/vcf#>
PREFIX vep:     <http://genome-variation.org/resource/vep#>
PREFIX snpeff:  <http://genome-variation.org/resource/snpeff#>
PREFIX mogplus: <http://identifiers.org/mogplus/ontology#>
PREFIX med2rdf: <http://med2rdf.org/ontology/med2rdf#>
PREFIX brso:    <http://purl.jp/bio/10/brso/>
PREFIX obo:     <http://purl.obolibrary.org/obo/>
PREFIX ensg:    <http://rdf.ebi.ac.uk/resource/ensembl/>
PREFIX mogbs:   <http://identifiers.org/mogplus/bioresource/>
PREFIX mgi:     <http://identifiers.org/mgi/>

SELECT ?variant ?consequence ?label ?impact
FROM <http://rdfportal.org/dataset/mogplus>
WHERE {
  ?variant vep:has_consequence ?ann .
  ?ann vep:consequence obo:SO_0001628 .

  OPTIONAL { ?ann vep:consequence_label ?label }
  OPTIONAL { ?ann vep:impact ?impact }

  BIND(obo:SO_0001628 AS ?consequence)
}
LIMIT 100

スキーマ図