データセット詳細

MBGD RDF

微生物比較ゲノムデータベースMBGDのRDFデータセット

データセット仕様

タグ	Genome Gene Phylogeny/Classification
提供元	Original
登録区分	Submitted
データ提供者
作成者	千葉啓和基礎生物学研究所西出浩世基礎生物学研究所内山郁夫National Institute for Basic Biology
公開日	2015-06-20
ライセンス	Creative Commons Attribution-ShareAlike 2.1 Japan (CC BY-SA 2.1 JP) MBGD RDF © MBGD development team, National Institute for Basic Biology licensed under Creative Commons Attribution-ShareAlike 2.1 Japan
バージョン	2015
ダウンロード	https://rdfportal.org/download/mbgd
SPARQLエンドポイント	https://rdfportal.org/primary/sparql

データセット統計

Triples: 1609018143

Subjects: 321276294

Properties: 50

Objects: 476343849

Classes: 32

SPARQLクエリ例

例 1

エンドポイントで実行

######
# Get orthologs of a given RefSeq ID
#

PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX orth: <http://purl.jp/bio/11/orth#>
PREFIX protid: <http://identifiers.org/ncbiprotein/>

SELECT DISTINCT ?protein_id
FROM <http://mbgd.genome.ad.jp/rdf/resource/default>
FROM <http://mbgd.genome.ad.jp/rdf/resource/gene>
WHERE {
    ?group a orth:OrthologGroup ;
        orth:member+/orth:gene?/orth:protein?/rdfs:seeAlso protid:NP_563687.1 ;
        orth:member+/orth:gene?/orth:protein?/rdfs:seeAlso ?protein_id .
    FILTER regex(?protein_id, "identifiers.org/ncbiprotein")
}

例 2

エンドポイントで実行

######
# Get orthologs of a given UniProt ID
#

PREFIX orth: <http://purl.jp/bio/11/orth#>
PREFIX mbgd: <http://purl.jp/bio/11/mbgd#>
PREFIX mbgdr: <http://mbgd.genome.ad.jp/rdf/resource/>
PREFIX uniprot: <http://purl.uniprot.org/uniprot/>

SELECT DISTINCT ?uniprot_id
FROM <http://mbgd.genome.ad.jp/rdf/resource/default>
FROM <http://mbgd.genome.ad.jp/rdf/resource/xref_uniprot>
WHERE {
    ?group a orth:OrthologGroup ;
        orth:inDataset mbgdr:default ;
        orth:member/orth:gene/mbgd:uniprot uniprot:K9Z723 ;
        orth:member/orth:gene/mbgd:uniprot ?uniprot_id .
}

例 3

エンドポイントで実行

######
# Get orthologs and their annotations for a given UniProt ID
#

PREFIX dct: <http://purl.org/dc/terms/>
PREFIX orth: <http://purl.jp/bio/11/orth#>
PREFIX mbgd: <http://purl.jp/bio/11/mbgd#>
PREFIX mbgdr: <http://mbgd.genome.ad.jp/rdf/resource/>
PREFIX uniprot: <http://purl.uniprot.org/uniprot/>

SELECT DISTINCT ?uniprot_id ?mbgd_gene_id ?gene_description ?organism
FROM <http://mbgd.genome.ad.jp/rdf/resource/default>
FROM <http://mbgd.genome.ad.jp/rdf/resource/xref_uniprot>
FROM <http://mbgd.genome.ad.jp/rdf/resource/gene>
FROM <http://mbgd.genome.ad.jp/rdf/resource/organism>
WHERE {
    ?group a orth:OrthologGroup ;
        orth:inDataset mbgdr:default ;
        orth:member/orth:gene/mbgd:uniprot uniprot:K9Z723 ;
        orth:member/orth:gene ?gene .
    ?gene dct:identifier ?mbgd_gene_id ;
        mbgd:uniprot ?uniprot_id ;
        dct:description ?gene_description ;
        orth:organism/dct:description ?organism .
}
ORDER BY ?organism

例 4

エンドポイントで実行

######
# List of MBGD default organisms
#

PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX dct: <http://purl.org/dc/terms/>
PREFIX orth: <http://purl.jp/bio/11/orth#>
PREFIX mbgd: <http://purl.jp/bio/11/mbgd#>
PREFIX mbgdr: <http://mbgd.genome.ad.jp/rdf/resource/>

SELECT DISTINCT ?mbgd_organism_id ?organism_name ?issued_date ?tax_id
FROM <http://mbgd.genome.ad.jp/rdf/resource/default>
FROM <http://mbgd.genome.ad.jp/rdf/resource/organism>
FROM <http://rdfportal.org/ontology/taxonomy>
WHERE {
    mbgdr:default orth:organism ?mbgd_organism_id .
    ?mbgd_organism_id dct:description ?organism_name ;
                      orth:taxon ?tax ;
                      dct:issued ?issued_date .
    ?tax_id rdfs:seeAlso ?tax .
}
ORDER BY ?issued_date

スキーマ図