データセット一覧

DBKERO RDF

ウェブサイト

DBKEROは細胞のマルチオミクスデータ（SNV, RNA-seq, ChIP-seq, BS-seq, TSS-seq）を集めたデータセットです。 ChIP-seq部分は巨大なため、簡略化したchip_seq_liteを収録しています。元の巨大なChIP-seqデータも https://rdfportal.org/rdf/download/kero/2017-01-27/all/chip_seq_all.tar.gz としてダウンロードできます。

データセット仕様

タグ
Genome Polymorphism Other DNA Gene expression Others
提供元 Original
登録区分 Submitted
データ提供者
作成者
  • 河野　信北里大学
  • 若栗　浩幸東京大学大学院新領域創成科学研究科
  • 鈴木　穣東京大学大学院新領域創成科学研究科
公開日 2020-06-10
ライセンス
  • Attribution 4.0 International (CC BY 4.0)
バージョン 2020-06-10
ダウンロード https://rdfportal.org/download/kero
SPARQLエンドポイント https://rdfportal.org/kero/sparql

データセット統計

Triples
11198913244
Subjects
965396936
Properties
60
Objects
7487172357
Classes
43

SPARQLクエリ例

例 1

エンドポイントで実行 
# SNV positions within 1000 bp upstream region of MT1A gene in A427 cell line
# Note the SPARQL endpoint for KERO is https://rdfportal.org/rdf/kero/sparql .


PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX owl: <http://www.w3.org/2002/07/owl#>
PREFIX dc: <http://purl.org/dc/elements/1.1/>
PREFIX dct: <http://purl.org/dc/terms/>
PREFIX dcat: <http://www.w3.org/ns/dcat#>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
PREFIX foaf: <http://xmlns.com/foaf/0.1/>
PREFIX sio: <http://semanticscience.org/resource/>
PREFIX so: <http://purl.obolibrary.org/obo/>
PREFIX dbpedia: <http://dbpedia.org/ontology/>
PREFIX snomed: <http://purl.bioontology.org/ontology/SNOMEDCT/>
PREFIX ensemblvariation: <http://rdf.ebi.ac.uk/terms/ensemblvariation/>
PREFIX faldo: <http://biohackathon.org/resource/faldo#>
PREFIX kero: <http://kero.hgc.jp/ontology/kero.owl#>

SELECT ?snv_position
WHERE
{
  ?rnadataset a kero:RNAseqDataset ;
    kero:hasExpressionData ?rnaseq ;
    kero:sample ?sample .
  ?sample a kero:SampleType ;
    rdfs:label "A427" .
  ?rnaseq a so:SO_0000673 ;
    skos:altLabel "MT1A" ;
    faldo:location ?rna_region .
  ?rna_region a faldo:Region ;
    faldo:begin ?begin ;
    faldo:reference ?chr .
  ?begin a ?direction ;
    faldo:position ?position .
  FILTER(?direction = faldo:ForwardStrandPosition OR ?direction = faldo:ReverseStrandPosition)
  BIND(IF(?direction = faldo:ForwardStrandPosition, ?position - 1000, ?position) AS ?5position)
  BIND(IF(?direction = faldo:ReverseStrandPosition, ?position + 1000, ?position) AS ?3position)
    ?snv a so:SO_0001483 ;
    faldo:location ?snv_location .
  ?snv_location a faldo:ExactPosition ;
    faldo:reference ?chr ;
    faldo:position ?snv_position .
  ?snvdataset a kero:SNVDataset ;
    kero:hasVariationSite ?snv ;
    kero:sample ?sample .
  FILTER(?snv_position > ?5position AND ?snv_position < ?3position)
}

例 2

エンドポイントで実行 
# List SNVs within 1000 bp upstream region of MT1A gene by each cell line
# Note the SPARQL endpoint for KERO is https://rdfportal.org/rdf/kero/sparql .

PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX owl: <http://www.w3.org/2002/07/owl#>
PREFIX dc: <http://purl.org/dc/elements/1.1/>
PREFIX dct: <http://purl.org/dc/terms/>
PREFIX dcat: <http://www.w3.org/ns/dcat#>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
PREFIX foaf: <http://xmlns.com/foaf/0.1/>
PREFIX sio: <http://semanticscience.org/resource/>
PREFIX so: <http://purl.obolibrary.org/obo/>
PREFIX dbpedia: <http://dbpedia.org/ontology/>
PREFIX snomed: <http://purl.bioontology.org/ontology/SNOMEDCT/>
PREFIX ensemblvariation: <http://rdf.ebi.ac.uk/terms/ensemblvariation/>
PREFIX faldo: <http://biohackathon.org/resource/faldo#>
PREFIX kero: <http://kero.hgc.jp/ontology/kero.owl#>

SELECT ?cell_line (COUNT(?snv_position) AS ?mutation_num)
WHERE
{
  ?rnadataset a kero:RNAseqDataset ;
    kero:hasExpressionData ?rnaseq ;
    kero:sample ?sample .
  ?sample a kero:SampleType ;
    rdfs:label ?cell_line .
  ?rnaseq a so:SO_0000673 ;
    skos:altLabel "MT1A" ;
    faldo:location ?rna_region .
  ?rna_region a faldo:Region ;
    faldo:begin ?begin ;
    faldo:reference ?chr .
  ?begin a ?direction ;
    faldo:position ?position .
  FILTER(?direction = faldo:ForwardStrandPosition OR ?direction = faldo:ReverseStrandPosition)
  BIND(IF(?direction = faldo:ForwardStrandPosition, ?position - 1000, ?position) AS ?5position)
  BIND(IF(?direction = faldo:ReverseStrandPosition, ?position + 1000, ?position) AS ?3position)
    ?snv a so:SO_0001483 ;
    faldo:location ?snv_location .
  ?snv_location a faldo:ExactPosition ;
    faldo:reference ?chr ;
    faldo:position ?snv_position .
  ?snvdataset a kero:SNVDataset ;
    kero:hasVariationSite ?snv ;
    kero:sample ?sample .
  FILTER(?snv_position > ?5position AND ?snv_position < ?3position)
}
GROUP BY ?cell_line

例 3

エンドポイントで実行 
# Dataset and Sample Metadata
# Note the SPARQL endpoint for KERO is https://rdfportal.org/rdf/kero/sparql .

PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX dcterms: <http://purl.org/dc/terms/>
PREFIX foaf: <http://xmlns.com/foaf/0.1/>
PREFIX kero: <http://kero.hgc.jp/ontology/kero.owl#>
PREFIX dcat: <http://www.w3.org/ns/dcat#>
PREFIX snomed: <http://purl.bioontology.org/ontology/SNOMEDCT/>
PREFIX sio: <http://semanticscience.org/resource/>
PREFIX dbponto: <http://dbpedia.org/ontology/>

SELECT DISTINCT ?dataset_type ?dataset ?title ?species ?sample_id ?sample_label ?sample_gender ?sample_age
FROM <http://rdfportal.org/dataset/kero/Cancer_Cell_Line> 
FROM <http://kero.hgc.jp/ontology/kero.owl> 
WHERE {
    ?dataset rdf:type ?dataset_type_uri .
    ?dataset_type_uri rdfs:label ?dataset_type .
    ?dataset_type_uri rdfs:subClassOf sio:SIO_000089 .
    ?dataset rdfs:label ?title .
    ?dataset dcat:theme / rdfs:label ?species .
    ?dataset kero:sample ?sample .
    ?sample dcterms:identifier ?sample_id .
    ?sample rdfs:label ?sample_label .
    OPTIONAL { 
      ?sample snomed:specimenOf ?person . 
      ?person foaf:gender ?sample_gender . 
      OPTIONAL { ?person dbponto:age ?sample_age . }
    }
}

スキーマ図

Schema diagram for kero
Schema diagram for kero