PREFIX dcterms: <http://purl.org/dc/terms/>
PREFIX obo: <http://purl.obolibrary.org/obo/>
PREFIX refexo: <http://purl.jp/bio/01/refexo#>

SELECT ?entry_id ?entry ?sample_id ?sample ?age ?desc AS ?description ?ev AS ?expression_value
FROM <http://refex.dbcls.jp/rdf/fantom5>
WHERE {
  ?entry refexo:refexSample ?sample .
  ?sample dcterms:identifier ?sample_id .
  ?entry dcterms:identifier ?entry_id .
  ?sample refexo:sex obo:PATO_0000383 .
  ?sample refexo:age ?age .
  ?sample refexo:refexRefinedDescription ?desc .
  ?entry refexo:expValue ?ev .
  FILTER(REGEX(?desc, "Smooth Muscle Cells"))
  FILTER(xsd:integer(?age) > 55)
  FILTER(xsd:float(?ev) > 7.0)
}

PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX dc: <http://purl.org/dc/elements/1.1/>
PREFIX dcterms: <http://purl.org/dc/terms/>
PREFIX refexs: <http://refex.dbcls.jp/sample/>
PREFIX refexo: <http://purl.jp/bio/01/refexo#>
PREFIX ff: <http://fantom.gsc.riken.jp/5/sstar/FF:>
PREFIX bs: <http://identifiers.org/biosample/>
PREFIX obo: <http://purl.obolibrary.org/obo/>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>

SELECT ?refexid ?refex ?gene ?ev AS ?expression_value ?sample ?age
FROM <http://refex.dbcls.jp/rdf/fantom5>
WHERE {
    ?sample ?p ?bn .
    ?bn refexo:belongsToAnatomy obo:UBERON_0000468 .
    ?sample refexo:sex obo:PATO_0000384 .
    ?sample refexo:age ?age_dat .
    ?refex a refexo:RefExEntry .
    ?refex dcterms:identifier ?refexid .
    ?refex refexo:refexSample ?sample .
    ?refex refexo:expValue ?val .
    ?refex rdfs:seeAlso ?gene .
    BIND(xsd:decimal(?age_dat) AS ?age)
    BIND(xsd:float(?val) AS ?ev)
    FILTER(?age > 20 && ?ev > 2 && REGEX(?gene, "identifiers.org", "i"))
} LIMIT 100

# Endpoint: https://rdfportal.org/primary/sparql
# Description: RDFized reference gene expresson dataset derived from CAGE and GeneChip experiments in the RefEx database.

PREFIX refexo: <http://purl.jp/bio/01/refexo#>
PREFIX dct: <http://purl.org/dc/terms/>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>

SELECT ?refex_id ?ex_value ?see_also ?RefExSample ?sample_id ?taxonomy ?age ?stage ?description ?cell_type ?disease ?dev_site ?refexo_sample
FROM <http://refex.dbcls.jp/rdf/fantom5>
FROM <http://refex.dbcls.jp/rdf/genechip>
FROM <http://purl.jp/bio/01/refexo>
WHERE {
    ?RefExEntry a refexo:RefExEntry ;
        dct:identifier ?refex_id ;
        refexo:expValue ?ex_value ;
        rdfs:seeAlso ?see_also ;
        refexo:refexSample ?RefExSample .
    ?RefExSample a refexo:RefExSample ;
        dct:identifier ?sample_id .
    OPTIONAL {
        ?RefExSample refexo:organism ?taxonomy .
    }
    OPTIONAL {
        ?RefExSample refexo:age ?age .
    }
    OPTIONAL {
        ?RefExSample refexo:developmentalStage ?stage .
    }
    OPTIONAL {
        ?RefExSample refexo:refexRefinedDescription ?description .
    }
    OPTIONAL {
        ?RefExSample refexo:sampleReference / refexo:belongsToCellType ?cell_type .
    }
    OPTIONAL {
        ?RefExSample refexo:sampleReference / refexo:belongsToDisease ?disease .
    }
    OPTIONAL {
        ?RefExSample refexo:sampleReference / refexo:belongsToDevelopmentSite ?dev_site .
    }
    OPTIONAL {
        ?RefExSample refexo:sampleReference / refexo:sample ?refexo_sample .
    }
}
LIMIT 100