######
# Find molecular entities in the PDB entry "1GOF" and their descriptions.
#

PREFIX pdbr: <http://rdf.wwpdb.org/pdb/>
PREFIX pdbo: <http://rdf.wwpdb.org/schema/pdbx-v50.owl#>

SELECT ?entity ?desc
FROM <http://rdfportal.org/dataset/pdbj>
WHERE {
  pdbr:1GOF ?cat ?ecats .
  ?ecats pdbo:has_entity ?entity .
  ?entity pdbo:entity.pdbx_description ?desc
}

######
# Find proteins in PDB and get amino acid sequences (limited to 10 hits)
#

PREFIX pdbo: <http://rdf.wwpdb.org/schema/pdbx-v50.owl#>

SELECT ?entity ?desc ?poly ?seq
FROM <http://rdfportal.org/dataset/pdbj>
WHERE {
  ?entity pdbo:referenced_by_entity_poly ?poly ;
          pdbo:entity.pdbx_description ?desc .
  ?poly pdbo:entity_poly.pdbx_seq_one_letter_code_can ?seq ;
        pdbo:entity_poly.type "polypeptide(L)"
} limit 10

######
# Find enzymes and their links to UniProt enzyme annotation (limited to 10 hits).
#

PREFIX pdbo: <http://rdf.wwpdb.org/schema/pdbx-v50.owl#> 

SELECT ?pdb ?entity ?desc ?ec
FROM <http://rdfportal.org/dataset/pdbj>
WHERE {
  ?entity pdbo:link_to_enzyme ?ec ;
          pdbo:entity.pdbx_description ?desc ;
          pdbo:of_datablock ?pdb .
} limit 10

######
# Find source organisms and links to taxonomy (limited to 10 hits).
#

PREFIX pdbo: <http://rdf.wwpdb.org/schema/pdbx-v50.owl#>

SELECT ?entity ?src ?name ?tax
FROM <http://rdfportal.org/dataset/pdbj>
WHERE {
  { ?entity pdbo:referenced_by_entity_src_gen ?src .
    ?src  pdbo:entity_src_gen.pdbx_gene_src_scientific_name ?name ;
          pdbo:link_to_taxonomy_source ?tax .
  }
  UNION
  { ?entity pdbo:referenced_by_entity_src_nat ?src .
    ?src pdbo:entity_src_nat.pdbx_organism_scientific ?name ;
         pdbo:link_to_taxonomy_source ?tax .
  }
} limit 10

# Endpoint: https://rdfportal.org/pdb/sparql
# Description: Reference UniProt

PREFIX pdbo: <https://rdf.wwpdb.org/schema/pdbx-v50.owl#>
PREFIX dct: <http://purl.org/dc/terms/>

SELECT ?pdb_id ?entity ?entity_id ?uniprot ?align_begin ?oligomeric_count
FROM <http://rdfportal.org/dataset/pdbj>
FROM <http://rdf.wwpdb.org/schema/pdbx-v50.owl>
WHERE {
    ?PDB a pdbo:datablock ;
        dct:identifier ?pdb_id ;
        pdbo:has_entityCategory / pdbo:has_entity ?entity ;
        pdbo:has_pdbx_struct_assemblyCategory / pdbo:has_pdbx_struct_assembly / pdbo:pdbx_struct_assembly.oligomeric_count ?oligomeric_count .
    ?entity a pdbo:entity ;
        pdbo:entity.id ?entity_id ;
        pdbo:referenced_by_struct_ref / pdbo:link_to_uniprot ?uniprot ;
        pdbo:referenced_by_struct_ref / pdbo:struct_ref.pdbx_align_begin ?align_begin .
}
LIMIT 100

# Endpoint: https://rdfportal.org/pdb/sparql
# Description: Experimental method

PREFIX pdbo: <https://rdf.wwpdb.org/schema/pdbx-v50.owl#>
PREFIX dct: <http://purl.org/dc/terms/>

SELECT ?pdb_id ?experimental_method
FROM <http://rdfportal.org/dataset/pdbj>
FROM <http://rdf.wwpdb.org/schema/pdbx-v50.owl>
WHERE {
    ?PDB a pdbo:datablock ;
        dct:identifier ?pdb_id ;
        pdbo:has_exptlCategory / pdbo:has_exptl / pdbo:exptl.method ?experimental_method .
}
LIMIT 100

# Endpoint: https://rdfportal.org/pdb/sparql
# Description: Helix list in a polypeptide chain
# Parameter: pdb_id: (example: 5KE7)
#            chain_id: (example: A)
#            conf_begin_chain_id: (example: A)
#            conf_type: (example: HELX_P)

PREFIX pdbo: <https://rdf.wwpdb.org/schema/pdbx-v50.owl#>
PREFIX dct: <http://purl.org/dc/terms/>

SELECT ?entity ?entity_id ?uniprot ?conformation ?conf_id ?pdb_id ?chain_id ?conf_begin_chain_id ?conf_type
FROM <http://rdfportal.org/dataset/pdbj>
FROM <http://rdf.wwpdb.org/schema/pdbx-v50.owl>
WHERE {
    VALUES ?pdb_id { "5KE7" }
    VALUES ?chain_id { "A" }
    VALUES ?conf_begin_chain_id { "A" }
    VALUES ?conf_type { "HELX_P" }
    ?PDB a pdbo:datablock ;
        pdbo:has_entityCategory / pdbo:has_entity ?entity ;
        dct:identifier ?pdb_id .
    ?entity a pdbo:entity ;
        pdbo:entity.id ?entity_id ;
        pdbo:referenced_by_struct_ref / pdbo:link_to_uniprot ?uniprot ;
        pdbo:referenced_by_struct_asym / pdbo:struct_asym.id ?chain_id .
    ?conformation a pdbo:struct_conf ;
        pdbo:struct_conf.beg_label_asym_id ?conf_begin_chain_id ;
        pdbo:struct_conf.conf_type_id ?conf_type .
    OPTIONAL {
        ?PDB pdbo:has_struct_confCategory / pdbo:has_struct_conf ?conformation .
        ?conformation pdbo:struct_conf.id ?conf_id .
    }
}
LIMIT 100

# Endpoint: https://rdfportal.org/pdb/sparql
# Description: Sheet strand list in a polypeptide chain
# Parameter: pdb_id: (example: 5KE7)
#            chain_id: (example: A)
#            sheet_strand_begin_chain_id: (example: A)

PREFIX pdbo: <https://rdf.wwpdb.org/schema/pdbx-v50.owl#>
PREFIX dct: <http://purl.org/dc/terms/>

SELECT ?entity ?entity_id ?uniprot ?sheet ?sheet_strand ?sheet_id ?sheet_strand_id ?pdb_id ?chain_id ?sheet_strand_begin_chain_id
FROM <http://rdfportal.org/dataset/pdbj>
FROM <http://rdf.wwpdb.org/schema/pdbx-v50.owl>
WHERE {
    VALUES ?pdb_id { "5KE7" }
    VALUES ?chain_id { "A" }
    VALUES ?sheet_strand_begin_chain_id { "A" }
    ?PDB a pdbo:datablock ;
        pdbo:has_entityCategory / pdbo:has_entity ?entity ;
        dct:identifier ?pdb_id .
    ?entity a pdbo:entity ;
        pdbo:entity.id ?entity_id ;
        pdbo:referenced_by_struct_ref / pdbo:link_to_uniprot ?uniprot ;
        pdbo:referenced_by_struct_asym / pdbo:struct_asym.id ?chain_id .
    ?sheet_strand a pdbo:struct_sheet_range ;
        pdbo:struct_sheet_range.beg_label_asym_id ?sheet_strand_begin_chain_id .
    OPTIONAL {
        ?PDB pdbo:has_struct_sheetCategory / pdbo:has_struct_sheet ?sheet .
        ?sheet a pdbo:struct_sheet ;
            pdbo:referenced_by_struct_sheet_range ?sheet_strand ;
            pdbo:struct_sheet.id ?sheet_id .
    }
    OPTIONAL {
        ?sheet_strand pdbo:struct_sheet_range.id ?sheet_strand_id .
    }
}
LIMIT 100