Datasets

PAConto

Website

PAConto is the RDF representation of PACDB (Pathogen Adherence to Carbohydrate Database) data and Ontology of Infectious Diseases known to be related to Glycan Binding. PACDB was developed by the Research Center for Medical Glycoscience (RCMG, AIST) and released in March 2010. At the present time PACDB provides information on about 370 strains of 120 microorganisms, and about 1,700 lectin-glycan interactions of two types: binding and not binding. Also, the PACDB provides information on about 100 infectious diseases in which the interaction between adherence molecules of pathogens and glycan ligands of the host cells plays an important role in the disease pathogenesis. All of the information for the creation of this database was obtained from scientific articles.

Dataset specifications

Tags
Other biomolecule Health/Disease Interaction/Pathway Structure
Provenance Original
Registration Submitted
Data provider
  • Glycoscience and Glycotechnology Research Group, Biotechnology Research Institute for Drug Discovery, National Institute of Advanced Industrial Science and Technology (AIST)
Creator
  • Hisashi NarimatsuGlycoscience and Glycotechnology Research Group, Biotechnology Research Institute for Drug Discovery, National Institute of Advanced Industrial Science and Technology (AIST)
  • Toshihide ShikanaiGlycoscience and Glycotechnology Research Group, Biotechnology Research Institute for Drug Discovery, National Institute of Advanced Industrial Science and Technology (AIST)
  • Elena SolovievaGlycoscience and Glycotechnology Research Group, Biotechnology Research Institute for Drug Discovery, National Institute of Advanced Industrial Science and Technology (AIST)
  • Noriaki FujitaGlycoscience and Glycotechnology Research Group, Biotechnology Research Institute for Drug Discovery, National Institute of Advanced Industrial Science and Technology (AIST)
Issued 2016-06-01
Licenses
  • Attribution NonCommercial ShareAlike 2.1 Japan (CC BY-NC-SA 2.1)
Version v.1.0
Download https://rdfportal.org/download/paconto
SPARQL Endpoint https://rdfportal.org/primary/sparql

Dataset statistics

Triples
81785
Subjects
9329
Properties
99
Objects
16451
Classes
60

SPARQL example queries

Example 1

Run on Endpoint 
#List species names and their strains names

PREFIX pacsch: <http://jcggdb.jp/rdf/diseases/paconto-schema#>
PREFIX glycan: <http://purl.jp/bio/12/glyco/glycan#>
PREFIX uniprot: <http://purl.uniprot.org/core/>
PREFIX ggdsch: <http://jcggdb.jp/rdf/diseases/ggdonto-schema#>

SELECT DISTINCT ?species_name ?strain_name
FROM <http://jcggdb.jp/rdf/diseases/paconto>
WHERE {
  ?species_uri ggdsch:conceptType pacsch:PathogenicMicroorganisms.
  ?species_uri uniprot:scientificName ?species_name.
  OPTIONAL {?species_uri glycan:has_strain ?strain_name.}
}
ORDER BY ?species_name ?strain_name

Example 2

Run on Endpoint 
#List pathogen adherence molecules of infectious agents which have a name like 'Escherichia coli'

PREFIX pacsch: <http://jcggdb.jp/rdf/diseases/paconto-schema#>
PREFIX uniprot: <http://purl.uniprot.org/core/>
PREFIX ggdsch: <http://jcggdb.jp/rdf/diseases/ggdonto-schema#>

SELECT DISTINCT ?pathogen_name
FROM <http://jcggdb.jp/rdf/diseases/paconto>
WHERE {
  ?pathogen_uri ggdsch:conceptType pacsch:PathogenAdherenceMolecules.
  ?pathogen_uri uniprot:scientificName ?scientific_name.
  FILTER regex(?scientific_name,"Escherichia coli","i")
  ?pathogen_uri pacsch:pathogenAdherMolecName ?pathogen_name.
}

Example 3

Run on Endpoint 
#List glycan ligands of hosts with which lectins of 'Haemophilus influenzae' pathogen have binding interactions

PREFIX pacsch: <http://jcggdb.jp/rdf/diseases/paconto-schema#>
PREFIX glycan: <http://purl.jp/bio/12/glyco/glycan#>
PREFIX uniprot: <http://purl.uniprot.org/core/>
PREFIX ggdsch: <http://jcggdb.jp/rdf/diseases/ggdonto-schema#>

SELECT DISTINCT ?glycan_name ?interaction_type
FROM <http://jcggdb.jp/rdf/diseases/paconto>
WHERE {
  ?pathogen_uri ggdsch:conceptType pacsch:PathogenAdherenceMolecules.
  ?pathogen_uri uniprot:scientificName ?scientific_name.
  FILTER regex(?scientific_name,"Haemophilus influenzae","i")
  ?pathogen_reference_uri a pacsch:AffinityInReference.
  ?pathogen_reference_uri glycan:has_affinity_to ?pathogen_uri.
  ?pathogen_reference_uri pacsch:describedInReference ?reference_uri.
  ?glycan_reference_uri a pacsch:InteractionInReference .
  ?glycan_reference_uri pacsch:describedInReference ?reference_uri.
  ?pathogen_uri pacsch:interactionInReference ?glycan_reference_uri .
  ?glycan_reference_uri pacsch:interactionType ?interaction_type .
  ?glycan_reference_uri pacsch:hasInteractionWith ?glycan_uri .
  ?glycan_uri a pacsch:GlycansPACDB .
  ?glycan_uri pacsch:carbohydrateLigandName ?glycan_name .
}

Example 4

Run on Endpoint 
#List PMID (from PubMed) for references in which described that lectin-glycan interactions play a role in Respiratory Tract Diseases

PREFIX pacsch: <http://jcggdb.jp/rdf/diseases/paconto-schema#>
PREFIX uniprot: <http://purl.uniprot.org/core/>
PREFIX ggdsch: <http://jcggdb.jp/rdf/diseases/ggdonto-schema#>
PREFIX gmsch: <http://jcggdb.jp/rdf/diseases/gmncbi-schema#>
PREFIX gdgsch: <http://jcggdb.jp/rdf/diseases/gdgdb-schema#>
PREFIX bibo: <http://purl.org/ontology/bibo/>

SELECT DISTINCT ?pmid
FROM <http://jcggdb.jp/rdf/diseases/paconto>
WHERE {
  ?disease_uri ggdsch:conceptType pacsch:DiseasesNameAndClass.
  ?disease_uri pacsch:diseaseClass ?disease_class .
  ?disease_uri gdgsch:diseaseNames ?disease_name .
  FILTER regex(?disease_class,"Respiratory Tract Disease","i")
  ?disease_uri gmsch:causedBy ?species_uri .
  ?species_reference_uri a pacsch:OccurInOrganismInReference.
  ?species_reference_uri uniprot:organism ?species_uri .
  ?species_reference_uri pacsch:describedInReference ?reference_uri.
  ?reference_uri ggdsch:conceptType pacsch:ReferencesData.
  ?reference_uri bibo:pmid ?pmid.
}

Schema diagram

Schema diagram for paconto
Schema diagram for paconto