### 01 ###
# Find Nikkaji Number, InChIKey, and InChI of the chemical compound which is named "Temporin"

define input:same-as "yes"
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX dct: <http://purl.org/dc/terms/>
PREFIX ssc: <http://semanticscience.org/resource/>

SELECT DISTINCT ?NikkajiNum ?InChIKey ?InChI
FROM <http://rdfportal.org/dataset/nikkaji/main>
FROM <http://rdfportal.org/dataset/nikkaji/inchi>

WHERE 
{ 
	?compound ?p "Temporin"@en ;
		dct:identifier ?NikkajiNum ;
		ssc:CHEMINF_000200 ?atr_inchikey, ?atr_inchi .
	?atr_inchikey rdf:type ssc:CHEMINF_000399 ;
		ssc:SIO_000300 ?InChIKey .
	?atr_inchi rdf:type ssc:CHEMINF_000396 ;
		ssc:SIO_000300 ?InChI .
}

#### 02 ####
# Find nikkaji compounds the names of which include "クロロメタン (Chloromethane)"

prefix dct: <http://purl.org/dc/terms/>
prefix foaf: <http://xmlns.com/foaf/0.1/>
prefix jst: <http://vocab.jst.go.jp/terms/sti#>
prefix jstd: <http://vocab.jst.go.jp/terms/vlist#>
prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
prefix rdfs: <http://www.w3.org/2000/01/rdf-schema#>
prefix xl: <http://www.w3.org/2008/05/skos-xl#>

SELECT  distinct ?nikkaji ?nikkajiNum ?labelName ?diagram ?query
FROM <http://rdfportal.org/dataset/nikkaji/main>

WHERE 
{ 
	?nikkaji 
		xl:altLabel ?o ; 
		dct:identifier ?nikkajiNum . 
		OPTIONAL{?nikkaji rdfs:label ?labelName filter ( lang(?labelName) = "en" ) .} 
		OPTIONAL{?nikkaji foaf:depiction ?diagram . } 
		OPTIONAL{?nikkaji jstd:systematic-name / rdf:first / rdfs:label ?systematicName .} 

	?o 
		rdf:rest* / rdf:first ?o2 . 

	?o2  
		xl:literalForm ?query filter (regex(?query,"クロロメタン")) . 

}
LIMIT 100

### 03 ###
# Find each DB entry such as PubChem corresponding with KNApSAcK metabolite:C00048658 (Clavatadine A, http://kanaya.naist.jp/knapsack_jsp/information.jsp?word=C00048658)

define input:same-as "yes"
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX dct: <http://purl.org/dc/terms/>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>

select distinct ?compound ?nikkajiNum ?label ?database
FROM <http://rdfportal.org/dataset/nikkaji/core>
FROM <http://rdfportal.org/dataset/nikkaji/link2jglobal_basedon_unichem>
FROM <http://rdfportal.org/dataset/nikkaji/link2jglobal_basedon_pubchem>

where{
	?compound skos:closeMatch <http://kanaya.naist.jp/knapsack_jsp/information.jsp?word=C00048658> ;
		dct:identifier ?nikkajiNum ;
		skos:exactMatch | skos:closeMatch ?database ;
		rdfs:label ?label filter (lang(?label)="en") .
}

### 04 ###
# Add information of DBpedia subjects to Nikkaji compounds by using InChIKey

define input:same-as "yes"
PREFIX jst: <http://vocab.jst.go.jp/terms/sti#>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX dct: <http://purl.org/dc/terms/>
PREFIX ssc: <http://semanticscience.org/resource/>
PREFIX dbp: <http://dbpedia.org/property/>

select distinct ?nikkaji ?NikkajiNum ?Label ?InChIKey ?dbpedia ?Subject

where 
{
	SERVICE <http://live.dbpedia.org/sparql>{
	?dbpedia dct:subject ?Subject ;
	dbp:stdinchikey ?InChIKey_tag BIND (STR(?InChIKey_tag) as ?InChIKey) .
	}

	GRAPH <http://rdfportal.org/dataset/nikkaji/core> {
	?nikkaji rdf:type jst:Chemical ;
		dct:identifier ?NikkajiNum ;
		rdfs:label ?Label filter (lang(?Label)="en") .
	}

	GRAPH <http://rdfportal.org/dataset/nikkaji/inchi> {
	?nikkaji ssc:CHEMINF_000200 ?atr_inchikey .
	?atr_inchikey rdf:type ssc:CHEMINF_000399 ;
		ssc:SIO_000300 ?InChIKey .
	}

} 
LIMIT 100

### 05 ###
# Discorver target proteins of Nikkaji compounds by using DrugBank 

define input:same-as "yes"
prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>  
prefix rdfs: <http://www.w3.org/2000/01/rdf-schema#>  
prefix skos: <http://www.w3.org/2004/02/skos/core#>

SELECT distinct ?compound ?label_compound ?kegg ?target ?label_target

where
{
	SERVICE <http://bio2rdf.org/sparql>{
	?drug <http://bio2rdf.org/drugbank_vocabulary:target> ?target ; 
		<http://bio2rdf.org/drugbank_vocabulary:x-kegg> ?kegg . 
	?target rdfs:label ?label_target .
	}

	GRAPH <http://rdfportal.org/dataset/nikkaji/link2jglobal_basedon_unichem>{
	?compound skos:closeMatch ?kegg .
	}
	
	GRAPH <http://rdfportal.org/dataset/nikkaji/core>{
	?compound rdfs:label ?label_compound filter (lang(?label_compound)="en") .  
	}
}