# Get NBRC microbial strains sampled from soil.

PREFIX mccv: <http://purl.jp/bio/10/mccv#>
PREFIX sio: <http://semanticscience.org/resource/>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
PREFIX meo: <http://purl.jp/bio/11/meo/>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>

select ?strain ?name ?meo ?meo_label
where {
?strain mccv:MCCV_000012 ?name .
?strain mccv:MCCV_000028 ?sample .
    ?sample mccv:MCCV_000072 ?habitat .
    ?habitat sio:SIO_000008 ?meo .
    ?meo rdfs:subClassOf meo:MEO_0000007 .
    ?meo rdfs:label ?meo_label
} LIMIT 100

# Get NBRC microbial strains with the growth temperature larger than 55.0.

PREFIX mccv: <http://purl.jp/bio/10/mccv#>
PREFIX sio: <http://semanticscience.org/resource/>
PREFIX mpo: <http://purl.jp/bio/10/mpo/> 
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#> 
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#> 
PREFIX obo: <http://purl.obolibrary.org/obo/>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>

select ?strain ?label ?temperature
where {
	?strain skos:prefLabel ?label.
    ?strain sio:SIO_000216 ?measurement_value.
    ?measurement_value sio:SIO_000221 obo:UO_0000027.
    ?measurement_value sio:SIO_000300 ?temperature.
	 FILTER(?temperature > 55)
	MINUS{
	    ?measurement_value rdf:type mpo:MPO_00104.
	}
} LIMIT 100