Datasets

MoG+ RDF

Website

MoG+ RDF is an RDF representation of MoG+ (Mouse Genome database with high added value), a mouse genomic variation database provided by the RIKEN BioResource Research Center. MoG+ provides genomic variation information for laboratory mouse strains, including wild-derived strains and classical inbred strains, and supports comparative analysis of genomic polymorphisms across mouse strains. Users of this RDF dataset should refer to the MoG+ Data Release Policy: https://molossinus.brc.riken.jp/mogplus3/about/policy The original MoG+ data files are available from: https://molossinus.brc.riken.jp/pub/

Dataset specifications

Tags
Genome Mouse Variation
Provenance Original
Registration Submitted
Data provider
  • RIKEN BioResource Research Center
Creator
  • Toyoyuki TakadaRIKEN BioResource Research Center
  • Hiroshi MasuyaRIKEN BioResource Research Center
Issued 2026-07-03
Licenses
  • https://molossinus.brc.riken.jp/mogplus3/about/policy
  • MoG+ is licensed under a Creative Commons Attribution (CC-BY) 4.0 License.
Download /website/download/#mogplus
SPARQL Endpoint https://rdfportal.org/primary/sparql

Dataset statistics

Triples
12376862684
Subjects
1405915030
Properties
70
Objects
1474488946
Classes
15

SPARQL example queries

Example 1

Run on Endpoint 
# Retrieve basic information about a variant

PREFIX rdf:     <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs:    <http://www.w3.org/2000/01/rdf-schema#>
PREFIX faldo:   <http://biohackathon.org/resource/faldo#>
PREFIX gvo:     <http://genome-variation.org/resource#>
PREFIX vcf:     <http://genome-variation.org/resource/vcf#>
PREFIX vep:     <http://genome-variation.org/resource/vep#>
PREFIX snpeff:  <http://genome-variation.org/resource/snpeff#>
PREFIX mogplus: <http://identifiers.org/mogplus/ontology#>
PREFIX med2rdf: <http://med2rdf.org/ontology/med2rdf#>
PREFIX brso:    <http://purl.jp/bio/10/brso/>
PREFIX obo:     <http://purl.obolibrary.org/obo/>
PREFIX ensg:    <http://rdf.ebi.ac.uk/resource/ensembl/>
PREFIX mogbs:   <http://identifiers.org/mogplus/bioresource/>
PREFIX mgi:     <http://identifiers.org/mgi/>

SELECT ?variant ?pos ?ref ?alt
FROM <http://rdfportal.org/dataset/mogplus>
WHERE {
  ?variant a ?type ;
           gvo:pos ?pos ;
           gvo:ref ?ref ;
           gvo:alt ?alt .

  FILTER(?type IN (gvo:SNV, gvo:Variation))
}
ORDER BY ?pos
LIMIT 100

Example 2

Run on Endpoint 
# Retrieve variants present in a specific strain (FLS_Shi)

PREFIX rdf:     <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs:    <http://www.w3.org/2000/01/rdf-schema#>
PREFIX faldo:   <http://biohackathon.org/resource/faldo#>
PREFIX gvo:     <http://genome-variation.org/resource#>
PREFIX vcf:     <http://genome-variation.org/resource/vcf#>
PREFIX vep:     <http://genome-variation.org/resource/vep#>
PREFIX snpeff:  <http://genome-variation.org/resource/snpeff#>
PREFIX mogplus: <http://identifiers.org/mogplus/ontology#>
PREFIX med2rdf: <http://med2rdf.org/ontology/med2rdf#>
PREFIX brso:    <http://purl.jp/bio/10/brso/>
PREFIX obo:     <http://purl.obolibrary.org/obo/>
PREFIX ensg:    <http://rdf.ebi.ac.uk/resource/ensembl/>
PREFIX mogbs:   <http://identifiers.org/mogplus/bioresource/>
PREFIX mgi:     <http://identifiers.org/mgi/>

SELECT ?variant ?pos ?ref ?alt ?genotype ?ad_ref ?ad_alt
FROM <http://rdfportal.org/dataset/mogplus>
WHERE {
  ?variant vcf:has_genotype_call ?call ;
           gvo:pos ?pos ;
           gvo:ref ?ref ;
           gvo:alt ?alt .

  ?call med2rdf:sample mogbs:FLS_Shi ;
        vcf:genotype ?genotype .

  OPTIONAL { ?call vcf:ad_ref ?ad_ref }
  OPTIONAL { ?call vcf:ad_alt ?ad_alt }
}
ORDER BY ?pos
LIMIT 100

Example 3

Run on Endpoint 
# Retrieve strains carrying a specific variant (GRCm39#3050118-G-A)

PREFIX rdf:     <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs:    <http://www.w3.org/2000/01/rdf-schema#>
PREFIX faldo:   <http://biohackathon.org/resource/faldo#>
PREFIX gvo:     <http://genome-variation.org/resource#>
PREFIX vcf:     <http://genome-variation.org/resource/vcf#>
PREFIX vep:     <http://genome-variation.org/resource/vep#>
PREFIX snpeff:  <http://genome-variation.org/resource/snpeff#>
PREFIX mogplus: <http://identifiers.org/mogplus/ontology#>
PREFIX med2rdf: <http://med2rdf.org/ontology/med2rdf#>
PREFIX brso:    <http://purl.jp/bio/10/brso/>
PREFIX obo:     <http://purl.obolibrary.org/obo/>
PREFIX ensg:    <http://rdf.ebi.ac.uk/resource/ensembl/>
PREFIX mogbs:   <http://identifiers.org/mogplus/bioresource/>
PREFIX mgi:     <http://identifiers.org/mgi/>

SELECT ?strain ?strain_label ?genotype ?ad_ref ?ad_alt ?dp
FROM <http://rdfportal.org/dataset/mogplus>
WHERE {
  <http://identifiers.org/mogplus/v3/1/GRCm39#3050118-G-A>
      vcf:has_genotype_call ?call .

  ?call med2rdf:sample ?strain ;
        vcf:genotype ?genotype .

  OPTIONAL { ?call vcf:ad_ref ?ad_ref }
  OPTIONAL { ?call vcf:ad_alt ?ad_alt }
  OPTIONAL { ?call vcf:sample_read_depth ?dp }
  OPTIONAL { ?strain rdfs:label ?strain_label }
}
ORDER BY ?strain_label
LIMIT 100

Example 4

Run on Endpoint 
# Retrieve variants within a specific coordinate range

PREFIX rdf:     <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs:    <http://www.w3.org/2000/01/rdf-schema#>
PREFIX faldo:   <http://biohackathon.org/resource/faldo#>
PREFIX gvo:     <http://genome-variation.org/resource#>
PREFIX vcf:     <http://genome-variation.org/resource/vcf#>
PREFIX vep:     <http://genome-variation.org/resource/vep#>
PREFIX snpeff:  <http://genome-variation.org/resource/snpeff#>
PREFIX mogplus: <http://identifiers.org/mogplus/ontology#>
PREFIX med2rdf: <http://med2rdf.org/ontology/med2rdf#>
PREFIX brso:    <http://purl.jp/bio/10/brso/>
PREFIX obo:     <http://purl.obolibrary.org/obo/>
PREFIX ensg:    <http://rdf.ebi.ac.uk/resource/ensembl/>
PREFIX mogbs:   <http://identifiers.org/mogplus/bioresource/>
PREFIX mgi:     <http://identifiers.org/mgi/>

SELECT ?variant ?pos ?ref ?alt
FROM <http://rdfportal.org/dataset/mogplus>
WHERE {
  ?variant gvo:pos ?pos ;
           gvo:ref ?ref ;
           gvo:alt ?alt ;
           faldo:location ?loc .

  ?loc faldo:reference <http://identifiers.org/mco/1/GRCm39> .

  FILTER(?pos >= 3050000 && ?pos <= 3100000)
}
ORDER BY ?pos

Example 5

Run on Endpoint 
# Retrieve variants located within a specific Ensembl gene (ENSMUSG00000051951)

PREFIX rdf:     <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs:    <http://www.w3.org/2000/01/rdf-schema#>
PREFIX faldo:   <http://biohackathon.org/resource/faldo#>
PREFIX gvo:     <http://genome-variation.org/resource#>
PREFIX vcf:     <http://genome-variation.org/resource/vcf#>
PREFIX vep:     <http://genome-variation.org/resource/vep#>
PREFIX snpeff:  <http://genome-variation.org/resource/snpeff#>
PREFIX mogplus: <http://identifiers.org/mogplus/ontology#>
PREFIX med2rdf: <http://med2rdf.org/ontology/med2rdf#>
PREFIX brso:    <http://purl.jp/bio/10/brso/>
PREFIX obo:     <http://purl.obolibrary.org/obo/>
PREFIX ensg:    <http://rdf.ebi.ac.uk/resource/ensembl/>
PREFIX mogbs:   <http://identifiers.org/mogplus/bioresource/>
PREFIX mgi:     <http://identifiers.org/mgi/>

SELECT ?variant ?pos ?ref ?alt
FROM <http://rdfportal.org/dataset/mogplus>
WHERE {
  ?variant mogplus:overlaps_gene ensg:ENSMUSG00000051951 ;
           gvo:pos ?pos ;
           gvo:ref ?ref ;
           gvo:alt ?alt .
}
ORDER BY ?pos

Example 6

Run on Endpoint 
# Search using a VEP consequence (ex. SO_0001628)

PREFIX rdf:     <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs:    <http://www.w3.org/2000/01/rdf-schema#>
PREFIX faldo:   <http://biohackathon.org/resource/faldo#>
PREFIX gvo:     <http://genome-variation.org/resource#>
PREFIX vcf:     <http://genome-variation.org/resource/vcf#>
PREFIX vep:     <http://genome-variation.org/resource/vep#>
PREFIX snpeff:  <http://genome-variation.org/resource/snpeff#>
PREFIX mogplus: <http://identifiers.org/mogplus/ontology#>
PREFIX med2rdf: <http://med2rdf.org/ontology/med2rdf#>
PREFIX brso:    <http://purl.jp/bio/10/brso/>
PREFIX obo:     <http://purl.obolibrary.org/obo/>
PREFIX ensg:    <http://rdf.ebi.ac.uk/resource/ensembl/>
PREFIX mogbs:   <http://identifiers.org/mogplus/bioresource/>
PREFIX mgi:     <http://identifiers.org/mgi/>

SELECT ?variant ?consequence ?label ?impact
FROM <http://rdfportal.org/dataset/mogplus>
WHERE {
  ?variant vep:has_consequence ?ann .
  ?ann vep:consequence obo:SO_0001628 .

  OPTIONAL { ?ann vep:consequence_label ?label }
  OPTIONAL { ?ann vep:impact ?impact }

  BIND(obo:SO_0001628 AS ?consequence)
}
LIMIT 100

Schema diagram

Schema diagram for mogplus
Schema diagram for mogplus