# Endpoint: https://rdfportal.org/ncbi/sparql
# Description: Retrieve attributes not in MGDEF, MGSAT, MGCONSO of C0023467 (Acute myeloid leukemia)
# Parameter: identifier: (example: C0023467)

PREFIX mo: <http://med2rdf/ontology/medgen#>
PREFIX dct: <http://purl.org/dc/terms/>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>

SELECT ?sty ?identifier ?label ?definition ?disease_has_associated_gene ?expanded_form_of ?has_alias ?has_expanded_form ?has_manifestation ?has_permuted_term ?inverse_isa ?isa ?manifestation_of ?undefined_relationship ?name_label
FROM <http://rdfportal.org/dataset/medgen>
WHERE {
    VALUES ?identifier { "C0023467" }
    ?MedGen a mo:ConceptID ;
        mo:sty ?sty ;
        dct:identifier ?identifier ;
        rdfs:label ?label ;
        skos:definition ?definition ;
        mo:disease_has_associated_gene ?disease_has_associated_gene ;
        mo:name / rdfs:label ?name_label .
    ?disease_has_associated_gene a mo:ConceptID ;
        mo:expanded_form_of ?expanded_form_of ;
        mo:has_alias ?has_alias ;
        mo:has_expanded_form ?has_expanded_form ;
        mo:has_manifestation ?has_manifestation ;
        mo:has_permuted_term ?has_permuted_term ;
        mo:inverse_isa ?inverse_isa ;
        mo:isa ?isa ;
        mo:manifestation_of ?manifestation_of ;
        mo:undefined_relationship ?undefined_relationship .
    ?expanded_form_of a mo:ConceptID .
    ?has_alias a mo:ConceptID .
    ?has_expanded_form a mo:ConceptID .
    ?has_manifestation a mo:ConceptID .
    ?has_permuted_term a mo:ConceptID .
    ?inverse_isa a mo:ConceptID .
    ?isa a mo:ConceptID .
    ?manifestation_of a mo:ConceptID .
    ?undefined_relationship a mo:ConceptID .
}
LIMIT 100

# Endpoint: https://rdfportal.org/ncbi/sparql
# Description: Retrieve MGDEF and MGSAT of C0023467 (Acute myeloid leukemia)
# Parameter: identifier: (example: C0023467)

PREFIX mo: <http://med2rdf/ontology/medgen#>
PREFIX dct: <http://purl.org/dc/terms/>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>

SELECT ?identifier ?mgdef_source ?definition ?mgdef_definition
FROM <http://rdfportal.org/dataset/medgen>
WHERE {
    VALUES ?identifier { "C0023467" }
    ?MedGen a mo:ConceptID ;
        dct:identifier ?identifier ;
        mo:mgdef / dct:source ?mgdef_source ;
        skos:definition ?definition ;
        mo:mgdef / skos:definition ?mgdef_definition .
}
LIMIT 100

# Endpoint: https://rdfportal.org/ncbi/sparql
# Description: Retrieve MGCONSO (link to external databases) of C0023467 (Acute myeloid leukemia)
# Parameter: identifier: (example: C0023467)

PREFIX mo: <http://med2rdf/ontology/medgen#>
PREFIX dct: <http://purl.org/dc/terms/>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>

SELECT ?identifier ?mgconso_aui ?mgconso_ispref ?mgconso_stt ?mgconso_ts ?mgconso_label ?mgconso_source
FROM <http://rdfportal.org/dataset/medgen>
WHERE {
    VALUES ?identifier { "C0023467" }
    ?MedGen a mo:ConceptID ;
        dct:identifier ?identifier ;
        mo:mgconso / mo:aui ?mgconso_aui ;
        mo:mgconso / mo:ispref ?mgconso_ispref ;
        mo:mgconso / mo:stt ?mgconso_stt ;
        mo:mgconso / mo:ts ?mgconso_ts ;
        mo:mgconso / rdfs:label ?mgconso_label ;
        mo:mgconso / dct:source ?mgconso_source .
}
LIMIT 100

# Endpoint: https://rdfportal.org/ncbi/sparql
# Description: Retrieve MGSAT of C0023467 (Acute myeloid leukemia)
# Parameter: identifier: (example: C0023467)

PREFIX mo: <http://med2rdf/ontology/medgen#>
PREFIX dct: <http://purl.org/dc/terms/>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>

SELECT ?identifier ?metaui ?stype ?mgsat_identifier ?mgsat_source ?mgsat_value ?metaui_label
FROM <http://rdfportal.org/dataset/medgen>
WHERE {
    VALUES ?identifier { "C0023467" }
    ?MedGen a mo:ConceptID ;
        dct:identifier ?identifier ;
        mo:mgsat / mo:metaui ?metaui ;
        mo:mgsat / mo:stype ?stype ;
        mo:mgsat / dct:identifier ?mgsat_identifier ;
        mo:mgsat / dct:source ?mgsat_source ;
        mo:mgsat / rdf:value ?mgsat_value ;
        mo:mgsat / rdfs:label ?metaui_label .
}
LIMIT 100

# Endpoint: https://rdfportal.org/ncbi/sparql
# Description: Retrieve PMIDs linked from C0023467 (Acute myeloid leukemia)
# Parameter: mengen_cid: (example: medgen:C0023467)

PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX mo: <http://med2rdf/ontology/medgen#>
PREFIX dct: <http://purl.org/dc/terms/>
PREFIX medgen: <http://www.ncbi.nlm.nih.gov/medgen/>

SELECT ?mengen_cid ?pubmed ?medgen_uid_label
FROM <http://rdfportal.org/dataset/medgen>
WHERE {
    VALUES ?mengen_cid { medgen:C0023467 }
    ?MedGenUid rdfs:seeAlso ?mengen_cid ;
        dct:references ?pubmed ;
        rdfs:label ?medgen_uid_label .
    ?mengen_cid a mo:ConceptID .
}
LIMIT 100