# List of species in the jPOST database
PREFIX jpost: <http://rdf.jpostdb.org/ontology/jpost.owl#>
PREFIX dct: <http://purl.org/dc/terms/>
SELECT DISTINCT ?dataset_id ?species
WHERE {
  ?dataset a jpost:Dataset ;
           dct:identifier ?dataset_id ;
           jpost:hasProfile/jpost:hasSample/jpost:species ?tax .
  ?tax <http://ddbj.nig.ac.jp/ontologies/taxonomy/scientificName> ?species .
}
ORDER BY ?dataset_id
LIMIT 20

# Count peptide spectrum matches of a protein
PREFIX jpost: <http://rdf.jpostdb.org/ontology/jpost.owl#>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX obo: <http://purl.obolibrary.org/obo/>
PREFIX up: <http://purl.uniprot.org/uniprot/>
SELECT DISTINCT ?sequence (COUNT (?psm) AS ?psm_count)
WHERE {
  VALUES ?uniprot { up:P01112 }
  ?protein jpost:hasDatabaseSequence ?uniprot ;
           jpost:hasPeptideEvidence/jpost:hasPeptide ?peptide .
  ?peptide jpost:hasSequence [ a obo:MS_1001344 ;
                             rdf:value ?sequence ] ;
           jpost:hasPsm ?psm .
}
ORDER BY DESC (?psm_count)

# Post-translational Phospholylartion sites of a protein
PREFIX jpost: <http://rdf.jpostdb.org/ontology/jpost.owl#>
PREFIX up: <http://purl.uniprot.org/uniprot/>
PREFIX unimod: <http://www.unimod.org/obo/unimod.obo#>
PREFIX faldo: <http://biohackathon.org/resource/faldo#>
SELECT ?pep_position ?mod_position ?site (COUNT (?site) AS ?detected_count)
WHERE {
  VALUES ?uniprot { up:Q9NYF8 }
  ?protein jpost:hasDatabaseSequence ?uniprot ;
           jpost:hasPeptideEvidence ?evidence .
  ?evidence faldo:location/faldo:begin/faldo:position ?pep_position ;
            jpost:hasPeptide/jpost:hasPsm ?psm .
  ?psm jpost:hasModification [ a unimod:UNIMOD_21 ;  # UNIMOD_21 = "Phospho"
                             jpost:modificationSite ?site ;
                             faldo:location/faldo:position ?mod_position ] .
}
ORDER BY ?pep_position ?mod_position