# List tags for databases

PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX tag: <http://integbio.jp/dbcatalog/dbcatalogtag.owl#>
PREFIX dcterms: <http://purl.org/dc/terms/>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>

SELECT ?tag_id ?tag_label_ja ?tag_label_en
FROM <http://rdfportal.org/dataset/dbcatalog/tag>
WHERE
{
  ?tag a skos:Concept ;
       dcterms:identifier ?tag_id .
  { ?tag rdfs:label ?tag_label_ja . FILTER (lang(?tag_label_ja) = "ja" ) }
  { ?tag rdfs:label ?tag_label_en . FILTER (lang(?tag_label_en) = "en" ) }
} ORDER BY ?tag_id

# List databases with taxonomy ID 9606 (human) and tag T0012 (drug) .

PREFIX dcat: <http://www.w3.org/ns/dcat#>
PREFIX dcterms: <http://purl.org/dc/terms/>
PREFIX db: <http://purl.jp/bio/03/dbcatalog/>
PREFIX tag: <http://integbio.jp/dbcatalog/dbcatalogtag.owl#>
PREFIX taxddbj: <http://ddbj.nig.ac.jp/ontologies/taxonomy/>

SELECT ?db ?nbdcid ?title_ja ?title_en
FROM <http://rdfportal.org/dataset/dbcatalog/main>
WHERE
{
  ?db dcat:theme taxddbj:9606 ;
      dcat:theme tag:T0012 ;
      dcterms:identifier ?nbdcid .
  { ?db dcterms:title ?title_ja . FILTER (lang(?title_ja) = "ja" ) } 
  OPTIONAL { ?db dcterms:title ?title_en . FILTER (lang(?title_en) = "en" ) }
}

# List databases with "ガン" or "癌" in its description

PREFIX dcterms: <http://purl.org/dc/terms/>
PREFIX db: <http://purl.jp/bio/03/dbcatalog/>

SELECT ?db ?title_ja ?title_en ?description 
FROM <http://rdfportal.org/dataset/dbcatalog/main>
WHERE
{
  {
    ?db dcterms:description ?description .
    FILTER ( CONTAINS(?description, "ガン" ) || CONTAINS(?description , "癌" ) ) 
  }
  { ?db dcterms:title ?title_ja . FILTER (lang(?title_ja) = "ja" ) } 
  OPTIONAL { ?db dcterms:title ?title_en . FILTER (lang(?title_en) = "en" ) }
}